Re: TC1025 comparator spice model

From: Johan Smit (smitjsno_at_spamlantic.net)
Date: 12/30/04 

Date: Thu, 30 Dec 2004 16:09:35 +0200

On Wed, 29 Dec 2004 14:04:26 -0700, Jim Thompson
<thegreatone@example.com> wrote:

>Hi Johan, I think the following is correct... I had to re-write it in
>subcircuit format... it is from some of my old stuff where I used to
>place everything inside the symbol. Give it a whirl. If it balks,
>let me know.

Hi Great One Jim,
I changed a few things to add the supply connections.
Here is the .Lib file :

.SUBCKT CompCMOS 1 2 3 4 5 PARAMS: DELTA=5m T=10n
** DELTA = Transition Width (Input, Volts)
** T = Delay
R1 int1 4 1G
R2 int1 int2 {SQRT(T/0.693147)}
C1 int2 4 {SQRT(T/0.693147)}
E2 5 4 VALUE = {V(int2,4)*V(3,4)+V(4)}
E1 int1 4 VALUE = {(tanh(A*V(1,2))+1)/2}
.PARAM A = 2.197774/DELTA
.ENDS CompCMOS

and the little capacity controlled oscillator

VS1025.CIR
.LIB CompCMOS.LIB
Vsupply Vs 0 3v
R1 2 5 1MEG
R2 5 7 470K
R3 6 7 220K
R4 1 2 220K
R5 7 0 100K ;load
C1 2 6 100PF ;CX
C2 2 0 200PF ;stray
C3 6 0 200PF ;stray
C4 Vs 0 100NF ;decoupling
XCOMP1 5 6 Vs 0 7 CompCMOS
XCOMP2 6 7 Vs 0 1 CompCMOS
.IC V(2)=1v
.tran 0.1u 1m 0 0
.probe

Works like a charm, but please check if I had not made a fool of
myself somewhere. I have done it before.
Thanks very much
Best Regards
Johan Smit