Re: TL431 SPICE with reactive components

On Sat, 2 Jul 2005 09:59:15 -0400, "Johnson" <jdwalton@xxxxxxxx>
wrote:

>I posted this to ABSE, but perhaps will get more feedback here. This is
>cobbled together from the Texas Instruments and OnSemi models -- works in
>Multisim but I am sure that there are some tweaks:
>
>*********************************************************************
>***** TL431 MODEL Adapted from Tex Instr and On Semi Models *********
>************ Includes Reactive Components ***************************
>*********************************************************************
>**** REF/FB
>**** | ANODE
>**** | | KATHODE
>**** | | |
>**** | | |
>.SUBCKT TL431 1 2 3
>EV1 11 2 VALUE = { IF (V(3,2)>2.495, 2.495, V(3,2))}
>R1 2 6 15.6
>C1 6 2 0.5U
>R2 6 7 100
>C2 7 4 0.08U
>R3 4 2 10
>G2 2 8 7 2 1.73
>D1 5 8 DCLAMP
>D2 3 8 DCLAMP
>V4 5 2 2
>G1 2 6 11 1 0.11
>.MODEL DCLAMP D (IS=13.5N RS=25M N=1.59 +CJO=45P VJ=0.75 M=0.302 TT=50.4N
>BV=36V IBV=1MA)
>ENDS
>

Here's two from my library. In the first I changed a POLY notation to
EVALUE. In the second I commented-out a NODESET... don't know why
that was ever there... really bad form to do that inside of a model.

******************************************************************
* REFERENCE
* | ANODE
* | | CATHODE
* | | |
..SUBCKT TL431/TI 1 2 3
V1 6 7 DC 1.4V
I1 2 4 1E-3
R1 1 2 1.2E6
R2 4 2 RMOD 2.495E3
R3 5 7 .2
D1 3 6 DMOD1
D2 2 3 DMOD1
D3 2 7 DMOD2
*E1 5 2 POLY(2) (4,2) (1,2) 0 710 -710
E1 5 2 VALUE = {V(4,2)*710 + V(1,2)*-710}
..MODEL RMOD RES (TC1=1.4E-5 TC2=-1E-6)
..MODEL DMOD1 D (RS=.3)
..MODEL DMOD2 D (RS=1E-6)
..ENDS
******************************************************************
..subckt TL431-R REFIN ANODE CATHODE
Q8 Q2_C Q2_C R4_N 0 P1
Q9 CATHODE Q7_C Q9_E 0 n1
R8 Q4_E ANODE 800
R9 Q2_E R9_N 4k
Q10 CATHODE R6_P ANODE 0 n1 5
Q11 Q7_C R10_P ANODE 0 n1
*.nodeset R3_N 1
C2 R9_N C2_N 20p
R10 R10_P R1_N 1k
C1 CATHODE Q7_C 20p
D1 ANODE Q7_C DIODE
D2 ANODE CATHODE DIODE
R4 CATHODE R4_N 800
Q2 Q2_C Q1_E Q2_E 0 n1
Q3 R9_N C2_N ANODE 0 n1
R5 CATHODE R5_N 800
R6 R6_P Q9_E 150
Q1 CATHODE REFIN Q1_E 0 n1
R7 ANODE R6_P 10k
Q6 Q7_C Q7_C REFIN 0 n1
Q7 Q7_C Q2_C R5_N 0 P1
R1 R3_N R1_N 2.4k
R2 R3_N C2_N 7.2k
Q4 C2_N R1_N Q4_E 0 n1
Q5 R1_N R1_N ANODE 0 n1
R3 Q1_E R3_N 3.28k
..model p1 pnp bf=50
..model n1 npn bf=100 tf=2n cjc=1p is=5e-18 NF=1.07
..model diode d rs=1 cjo=2p
..ends
******************************************************************


...Jim Thompson
--
| James E.Thompson, P.E. | mens |
| Analog Innovations, Inc. | et |
| Analog/Mixed-Signal ASIC's and Discrete Systems | manus |
| Phoenix, Arizona Voice:(480)460-2350 | |
| E-mail Address at Website Fax:(480)460-2142 | Brass Rat |
| http://www.analog-innovations.com | 1962 |

I love to cook with wine. Sometimes I even put it in the food.
.

Quantcast