Re: Wanted: LM-709 (Spice model) National Op-Amp

"Neil" <neilwrites2@xxxxxxxxxxx> schrieb im Newsbeitrag
news:1126944635.562276.150550@xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
> Looking for a spice model or subcircuit netlist for the LM709 from
> National semiconductor. I asked intusoft, cause they have a free model
> service. I bought their entry level software ICAP/4 8.3.3 from a dealer
> purchased in 2000. For reasons I won't mention, I was denied the
> request from their sales department.
>
> I was going to email National, but from what I read in Bob's book
> "Troubleshooting Analog circuits" he doesn't like S.P.I.C.E.
> and for good reason...........:)
>
> Any help on this request would be great....
>
> Thanks
> Neil


Hello Neil,

If you look with Google (uA709 spice) then you will find two
sources for a model.
One is in the library file "opamp.lib" from Microsim/Cadence.
It's a very old behavioral model and I have not tested it.
I don't have a PSPICE license and so I don't would use it.

In this "summer2000.pdf" is a netlist of a test circuit with
the LM/uA709. It's nothing else than an exact copy of the
schematic of the LM709 from National's data***.
http://www.spectrum-soft.com/down/summer2000.pdf

http://www.national.com/ds.cgi/LM/LM709.pdf

I used this data*** and made my own model. I would be
interested to get some feedback about the parameters of my
"invented" transistor models. I have used the reference
designators from the the data*** to make it easier to
modify the model if necessary.
THe model agrees very well with the performance of the data***.
It's a free model. Feel free to use/copy/modify.

I have also made a complete example for LTspice with
a schematic based on a nice symbol and a model file.
Additionally I have made a hierachical block design
which allows to probe down the hierarchy (in the schematic)
to every node of the LM709.

LTspice is free SPICE from www.linear.com .
http://ltspice.linear.com/software/swcadiii.exe

The LTspice user group:
http://groups.yahoo.com/group/LTspice

Download the files from here within the Yahoo group.

Files > Lib > LM709_uA709

Best regards,
Helmut




* LM709 SPICE Model
* Data***: http://www.national.com/ds.cgi/LM/LM709.pdf
* Helmut Sennewald
*
* Input compensation B (8) --------------------\
* Input compensation A (1) -----------------\ |
* Output compensation (5) --------------\ | |
* Output (6) -----------------------\ | | |
* Negative supply (4) ----------\ | | | |
* Positive supply (7) -------\ | | | | |
* Inverting input (2) ----\ | | | | | |
* non-inverting input(3) | | | | | | |
* | | | | | | | |
..subckt LM709 In+ In- V+ V- OUT COMP A B
Q7 v+ N001 N005 0 NPN1
R5 v+ N001 10k
Q3 N001 N006 N003 0 NPN1
Q4 N001 N003 N002 0 NPN1
R1 N005 N006 25k
R3 N003 N004 3k
Q15 N004 N004 N002 0 NPN1
R2 N005 A 25k
Q2 A in- N007 0 NPN1
Q1 N006 in+ N007 0 NPN1
Q5 B A N009 0 NPN1
R4 N009 N004 3k
Q6 B N009 N002 0 NPN1
R6 v+ B 10k
R8 N002 N011 3.6k
R10 N011 N010 10k
Q10 N010 N010 V- 0 NPN1
Q11 N007 N010 N008 0 NPN1
R11 N008 V- 2.4k
R9 N012 N011 10k
Q8 v+ B N013 0 NPN1
R7 N013 N012 1k
Q9 comp N002 N012 0 PNP1
R13 N014 V- 75
R12 comp N014 10k
Q12 N015 comp N014 0 NPN1
Q13 V- N015 out 0 PNP1
Q14 v+ N015 out 0 NPN1
R14 v+ N015 20k
R15 N012 out 30k
..MODEL NPN1 NPN (BF=100 VAF=50 RB=100 CJE=4P CJC=2P CJS=2P TF=0.5N TR=10N)
..MODEL PNP1 PNP (BF=15 VAF=50 CJC=4P CJE=8P RB=100 TF=20N TR=200N)
..ends LM709

.