Re: Which one is bigger?

In article <1135021700.598782.225820@xxxxxxxxxxxxxxxxxxxxxxxxxxxx>,
"oercim" <oercim@xxxxxxxxx> wrote:

> Hello, I have a problem. Let C and A be such matrices
>
> | 1 0 0 0 | | 1 1 1 1 |
> C=| a 1 0 0 | , A=| 1 1 1 1 |
> | a^2 a 1 0 | | 1 1 1 1 |
> | a^3 a^2 a 1 | | 1 1 1 1 |
>
> And let define Z=C*A*C' , M=C*C' and define,
>
> SUM1=sum((i=1 to4)sum(j=1 to 4))(Zij^2)
> SUM2=sum((i=1 to4)sum(j=1 to 4))(Mij^2)
>
> (SUM1 is the sum of square of all elements of Z matrix
> and
> SUM2 is the sum of square of all elements of M
> matrix)
>
> It is obvious that for any a such that a>0 , SUM1>SUM2, but
> what about for a<0 , which one is bigger, SUM1 or SUM2 ? Or does it
> depend on the value of a?

It depends on the value of a. For the 4 x 4 problem, the value of a for
for which SUM1>SUM2 is

a > Root[2 #^11 + 4 #^10 + 14 #^9 + 22 #^8 + 44 #^7 + 52 #^6 +
74 #^5 + 67 #^4 + 66 #^3 + 40 #^2 + 24 # + 6 &, 1]

that is, the first root of

2 x^11 + 4 x^10 + 14 x^9 + 22 x^8 + 44 x^7 + 52 x^6 +
74 x^5 + 67 x^4 + 66 x^3 + 40 x^2 + 24 x + 6

which is, numerically,

a > -0.3769461667603363...

> Note : Here C and A are 4*4 matrices but i am intetrested with all n*n
> matrices which have the same pattern).

For the n x n matrix, the value of a is the first root of a polynomial
of degree 4 n - 5. Numerically, the value of a decreases monitonically
with increasing n. For n = 15, the condition is

a > -0.530098...

Here is a Mathematica program for computing a as a function of n:
First set up the matrices C and A:

c[n_] := SparseArray[{{i_,i_}-> 1, {i_,j_} /; i > j -> a^(i-j)}, {n,n}]
a[n_] := SparseArray[{}, {n, n}, 1]

Define Z and M

z[n_] := c[n] . a[n] . Transpose[c[n]]
m[n_] := c[n] . Transpose[c[n]]

Define SUM1 and SUM2

sum[1][n_] := Total[z[n]^2, 2] // Factor
sum[2][n_] := Total[m[n]^2, 2] // Factor

Compute the condition on a under which SUM1>SUM2, here for n = 3.

Reduce[sum[1][3] > sum[2][3], a]

a > Root[2 #^7 + 4 #^6 + 12 #^5 + 14 #^4 + 22 #^3 + 16 #^2 +
12 # + 3 &, 1]

Evaluate this numerically.

N[%]

a > -0.3458617478958832

Cheers,
Paul

_______________________________________________________________________
Paul Abbott Phone: 61 8 6488 2734
School of Physics, M013 Fax: +61 8 6488 1014
The University of Western Australia (CRICOS Provider No 00126G)
AUSTRALIA http://physics.uwa.edu.au/~paul
.