Re: An exact simplification challenge - 35 (EllipticK, EllipticPi) - Go and surpass all CASs

Interestingly,

In[9]:= D[(n - 1) (EllipticK[n^2] - 2 EllipticPi[n, n^2]),
n] // Simplify

Out[9]= 0

Meaning that this value is a piecewise constant. Both EllipticK
and EllipticPi above are continuous for -1 < n < 1.
Hence for this interval

(n - 1) (EllipticK[n^2] - 2 EllipticPi[n, n^2]) == c

is constant.

Evaluating it for n==0 we get

In[11]:= With[{n =
0}, (n - 1) (EllipticK[n^2] - 2 EllipticPi[n, n^2])]

Out[11]= Pi/2

This completes the proof. Few words are in order as to how
to arrive to the aforementioned result.

In[15]:= ((1/Sqrt[z (1 - z) (2 - z)] (z (2 - z))/(2 - 2 z + z^2)
Dt[z]) /. z -> (2 + Sqrt[2]) (t - 1)/(t - (3 + 2 Sqrt[2]))) /.
Dt[t] -> 1 //
FullSimplify[(-2 + Sqrt[
2]) (t + 3 + 2 Sqrt[2]) (1 - t)/((3 + 2 Sqrt[2] + t^2)
Sqrt[(1 - (17 - 12 Sqrt[2]) t^2) (1 - t^2)])/#, 1 > t > -1] &

Out[15]= -(((-2 + 3/Sqrt[2]) (-2 + Sqrt[2]) (-3 - 2 Sqrt[2] +
t)^2 (3 + 2 Sqrt[2] + t) (10 + 7 Sqrt[2] + (2 + Sqrt[2]) t^2))/(
Sqrt[2 + Sqrt[
2]] (4 + 3 Sqrt[2] + Sqrt[2] t) (3 + 2 Sqrt[2] +
t^2) Sqrt[((3 + 2 Sqrt[2] - t)^3 (1 + (-17 + 12 Sqrt[2]) t^2))/(
10 + 7 Sqrt[2] + (2 + Sqrt[2]) t)]))

Mathematica can not prove that the above expression is actually 1.
We can verify this:

In[21]:= {D[%, t], %^2} // Simplify

Out[21]= {0, 1}

In[22]:= %% /. t -> {-1, -1/2, 0, 1/2, 1} // FullSimplify

Out[22]= {1, 1, 1, 1, 1}

We make further substitution of t==JacobiSN[u, 17-12*Sqrt[2]] :

In[23]:= (-2 + Sqrt[
2]) (t + 3 + 2 Sqrt[2]) (1 - t)/((3 + 2 Sqrt[2] + t^2)
Sqrt[(1 - (17 - 12 Sqrt[2]) t^2) (1 - t^2)]) Dt[t] /.
t -> JacobiSN[u, (17 - 12 Sqrt[2])] //
FullSimplify[#,
JacobiCN[u, 17 - 12 Sqrt[2]] > 0 &&
JacobiDN[u, 17 - 12 Sqrt[2]] > 0] &

Out[23]= -(((-2 + Sqrt[2]) Dt[
u] (-1 + JacobiSN[u, 17 - 12 Sqrt[2]]) (3 + 2 Sqrt[2] +
JacobiSN[u, 17 - 12 Sqrt[2]]))/(
3 + 2 Sqrt[2] + JacobiSN[u, 17 - 12 Sqrt[2]]^2))

Now, integrate it:

In[24]:= Integrate[ (-1 + JacobiSN[u, m]) (a + JacobiSN[u, m])/(
a + JacobiSN[u, m]^2), u] //
FullSimplify[#, JacobiDN[u, m] > 0] & //
Collect[#, _ArcTan | _EllipticPi] &

Out[24]= u + ((1 - a) ArcTan[(Sqrt[-1 - a m] JacobiCN[u, m])/(
Sqrt[1 + a] JacobiDN[u, m])])/(Sqrt[1 + a] Sqrt[-1 - a m]) -
2 EllipticPi[-(1/a), JacobiAmplitude[u, m], m]

In[25]:= e = % (2 - Sqrt[2]) /. {u -> InverseJacobiSN[t, m]} /. {m ->
17 - 12 Sqrt[2], a -> 3 + 2 Sqrt[2]};

One can check continuity with Plot. Then

In[26]:= (e /. t -> -1) - (e /. t -> 1) // Expand

Out[26]= -4 EllipticK[17 - 12 Sqrt[2]] +
2 Sqrt[2] EllipticK[17 - 12 Sqrt[2]] +
8 EllipticPi[-(1/(3 + 2 Sqrt[2])), 17 - 12 Sqrt[2]] -
4 Sqrt[2] EllipticPi[-(1/(3 + 2 Sqrt[2])), 17 - 12 Sqrt[2]]

In[27]:= FullSimplify[%]

Out[27]= 2 (-2 + Sqrt[2]) (EllipticK[17 - 12 Sqrt[2]] -
2 EllipticPi[-3 + 2 Sqrt[2], 17 - 12 Sqrt[2]])

This is exactly the result

e2 = With[{n =
Sqrt[8] - 3}, (n - 1) (EllipticK[n^2] - 2 EllipticPi[n, n^2])];


Sasha

On Jul 19, 4:47 pm, sashap <pav...@xxxxxxxxx> wrote:
Hi,

The answer is Pi/2 as is easy to see from numerical evaluation:

In[43]:= w = 1/Sqrt[2];

In[44]:= e1 = (1 + I) w EllipticPi[(1 - I) w^2,
w^2] + (1 - I) w EllipticPi[(1 + I) w^2, w^2] - EllipticK[w^2]/
w;

In[45]:= N[e1, 100] - Pi/2

Out[45]= 0.*10^-100 + 0.*10^-100 I

Representing each elliptic integral using its defining integral
representation,
and combining them into a single integral we find the integrand:

In[46]:= FullSimplify[
1/2 (1 + I) w 1/(1 - (1 - I) w^2 z) 1/Sqrt[z (1 - z) (1 - w^2 z)] +
1/2 (1 - I) w 1/(1 - (1 + I) w^2 z) 1/Sqrt[
z (1 - z) (1 - w^2 z)] - 1/2 1/w 1/Sqrt[z (1 - z) (1 - w^2 z)] ==
1/Sqrt[z (1 - z) (2 - z)] (z (2 - z))/(2 - 2 z + z^2), 0 < z < 1]

Out[46]= True

Thus the combination proposed equals

Integrate[1/Sqrt[z (1 - z) (2 - z)] (z (2 - z))/(2 - 2 z + z^2), {z,
0, 1}]

While I can not prove it, most likely Vladimir obtained the above
expression
from differentiating an elementary expression with ArcTan of a
radical. Axiom
chokes while looking for the anti-derivative:

==>> Error detected within library code:

integrate: implementation incomplete (residue poly has multiple non-
linear factors)
==

Attempting to find an explicitly real value for this integral gives
(steps are
too involved to show here):

In[58]:= e2 = With[{n = Sqrt[8]-3},
(n-1) (EllipticK[n^2] - 2 EllipticPi[n, n^2])];

In[59]:= N[e2, 500] - Pi/2

Out[59]= 0.*10^-500

While this is still far from the expected Pi/2, it is still nicer than
e1.

Oleksandr Pavlyk,
Special Functions Developer
Wolfram Research

P.S. And unless you came across this integral accidentally it is well
worth
writing an article about it, or post it to the newsgroup at least :)

On Jul 19, 4:29 am, Vladimir Bondarenko <v...@xxxxxxxxxxxxxxx> wrote:

Hello Computer Algebra Warriors,

None of the modern computer algebra systems succeeds
here in a direct fashion.

Is there a Whiz the Simplifier to invent the steps to
compress (much :) this nice expression

w := 1/sqrt(2):

(1 + I)*w*EllipticPi((1 - I)*w^2, w)
+ (1 - I)*w*EllipticPi((1 + I)*w^2, w)
- EllipticK(w)/w;

?

(A home task for my enemies: find a book or a paper etc
from where I (as you can think) stole this; if you can
and quote, I pay each my reporting enemy 1000 USD)

(My friends and supporters, don't worry ;-) It's just
yet another formula I got this morning out of my mind.)

Best wishes,

Vladimir Bondarenko

VM and GEMM architect
Co-founder, CEO, Mathematical Director

http://www.cybertester.com/Cyber Tester, LLChttp://maple.bug-list.org/ Maple Bugs Encyclopaediahttp://www.CAS-testing.org/CAS Testing


.