Re: An exact 1-D integration challenge - 53 - Proud Earthling, go and defeat all the doltish CASs!

On Feb 23, 11:14 pm, sashap <pav...@xxxxxxxxx> wrote:
The answer is zero. Here is a motivation for such an answer:

In[1]:= integrand =
z Sin[Log[z]] (z Cos[Log[z]] + 1)/(2 z Cos[Log[z]] + z^2 + 1)^2 ;

In[2]:= NIntegrate[integrand, {z, 0, Infinity}]

< message suppressed >

Out[2]= 0.*10^-6

change variables:

In[3]:= Refine[integrand Dt[z] /. z -> Exp[t] /. Dt[t] -> 1,
t \[Element] Reals] // FullSimplify // ExpToTrig

Out[3]= (Sin[
t] (1 + Cos[t] Cosh[t] + Cos[t] Sinh[t]))/(4 (Cos[t] + Cosh[t])^2)

fold integration over real line into integration over positives

In[4]:= (%) + (% /. t -> -t) // FullSimplify // TrigExpand

Out[4]= (Cos[t] Sin[t] Sinh[t])/(2 (Cos[t] + Cosh[t])^2)

Find an anti-derivative:

In[5]:= ant[t_] = Integrate[%, t]

Out[5]= 1/8 ((-1 + I) E^(I t)
Hypergeometric2F1[1/2 - I/2, 1,
3/2 - I/2, -E^((-1 + I) t)] - (1 - I) E^
t Hypergeometric2F1[1/2 - I/2, 1,
3/2 - I/2, -E^((1 + I) t)] + (1 + I) E^-t Hypergeometric2F1[
1/2 + I/2, 1, 3/2 + I/2, -E^((-1 + I) t)] + (1 + I) E^(I t)
Hypergeometric2F1[1/2 + I/2, 1,
3/2 + I/2, -E^((1 + I) t)] + (1 + I) Cosh[
t] Sec[(1/2 + I/2) t] Sech[t/2] Sin[t/2] + (1 - I) Cosh[t] Sech[
t/2] Sech[(1/2 + I/2) t] Sin[t/2] + 2 Sinh[t] -
Sech[t/2] Sinh[(3 t)/2] + Tanh[t/2])

verify the anti-derivative:

In[6]:= D[ant[t], t] // FullSimplify

Out[6]= (Sin[2 t] Sinh[t])/(4 (Cos[t] + Cosh[t])^2)

By applying
http://functions.wolfram.com/HypergeometricFunctions/Hypergeometric2F...

one can rewrite the anti-derivative as:

ant2[t_] =
(-1+I)/8 Exp[I t] Hypergeometric2F1[(1-I)/2,1,(3-I)/2, -Exp[-(1-
I)t]] +
(-1-I)/8 Exp[-I t] Hypergeometric2F1[1,(1+I)/2,(3+I)/2, -Exp[-
(1+I)t]] +
(1+I)/8 Exp[-t] Hypergeometric2F1[(1+I)/2,1,(3+I)/2, -Exp[-(1-
I)t]] +
(1-I)/8 Exp[-t] Hypergeometric2F1[1,(1-I)/2,(3-I)/2, -Exp[-
(1+I)t]] +
(Cosh[t] Sin[t] + Cos[t] Sinh[t])/(4 (Cos[t] + Cosh[t])) +
I Pi/4 Cosh[ Pi Floor[1/2 - t/(2 Pi)]] *
Cos[ Pi Floor[1/2 - t/(2 Pi)]] Sech[Pi/2];

Then, also verify its validity:

In[8]:= D[ant2[t], t] /. Floor'[x_] -> 0 // FullSimplify

Out[8]= (Sin[2 t] Sinh[t])/(4 (Cos[t] + Cosh[t])^2)

Note that the except for the last term, the anti-derivative is real
valued and continuous (plot
the real part).

It also vanishes on both ends of integration, i.e. 0 and Infinity.

Actually, the imaginary piece can be discarded at all (which is what
is
done by /. Floor'[x_] -> 0 ). Thus the smooth anti-derivative:


In[91]:= ad[
t_] = (-(1/8) + I/8) Exp[I t] Hypergeometric2F1[1/2 - I/2, 1,
3/2 - I/2, -Exp[(-1 + I) t]] - (1/8 + I/
8) Exp[-I t] Hypergeometric2F1[1, 1/2 + I/2,
3/2 + I/2, -Exp[(-1 - I) t]] + (1/8 + I/8) Exp[-t]
Hypergeometric2F1[1/2 + I/2, 1,
3/2 + I/2, -Exp[t (-1 + I)]] + (1/8 - I/
8) Exp[-t] Hypergeometric2F1[1, 1/2 - I/2,
3/2 - I/2, -Exp[(-1 - I) t]] + (
Cosh[t] Sin[t] + Cos[t] Sinh[t])/(4 (Cos[t] + Cosh[t]));

In[92]:= D[ad[t], t] // FullSimplify

Out[92]= (Sin[2 t] Sinh[t])/(4 (Cos[t] + Cosh[t])^2)

The anti-derivative is pure real, as seen from its summation form:

In[121]:=
summand[k_, t_] := ((-1)^
k Exp[-(1 + k) t] (Cos[k t] -
Exp[t] Cos[(1 + k) t] - (1 + 2 k) (Sin[k t] +
Exp[t] Sin[(1 + k) t])))/(4 (1 + 2 k + 2 k^2))

In[122]:=
Sum[summand[k, t], {k, 0, Infinity}] + (
Cosh[t] Sin[t] + Cos[t] Sinh[t])/(4 (Cos[t] + Cosh[t])) ==
ad[t] // FullSimplify

Out[122]= True

Now we can look at the limits. Lower limit is easier
to find using summation representation, which follows

In[147]:=
Sum[summand[k, 0], {k, 0, Infinity}] + ((
Cosh[t] Sin[t] + Cos[t] Sinh[t])/(4 (Cos[t] + Cosh[t])) /. t -> 0)

Out[147]= 0

to be zero.

The upper limit:

In[145]:= Limit[ad[t], t -> Infinity]

Out[145]= 0

Thus the value of the integral equals zero.

Oleksandr


The integral is purely real, since the integrand is, thus the
imaginary part can be discarded.
We thus has a half-baked proof that the integral equals zero.

Oleksandr Pavlyk

On Feb 23, 2:19 am, Vladimir Bondarenko <v...@xxxxxxxxxxxxxxx> wrote:

Hello dear computer algebra patriot the Earthling,

You know from my alarm messages to the human race, yes, those
disastrous (striped!) Computers are coming!...

We have the only choice, to protect our old good carbon-based
life! (I even do not want to think about the alternative 8-*)

So get prepared for the Last Combat. Train hard, fight easy!

Look, none of these silicon crystals can cracks this. After
a span of amateurish fuss, Mathematica/Maple/Derive/AXIOM
return this unevaluated, MuPAD keeps threshing for hours...

Is there a Super Duper Integrator the Warrior who can come up
with the CAS commands to obtain the exact value of

int(

z*sin(ln(z))*(z*cos(ln(z))+1)/(2*z*cos(ln(z))+z^2+1)^2,

z=0..infinity);

and rejoice ?
Cheers,

Vladimir Bondarenko

VM and GEMM architect
Co-founder, CEO, Mathematical Director

http://www.cybertester.com/Cyber Tester, LLChttp://maple.bug-list.org/ Maple Bugs Encyclopaediahttp://www.CAS-testing.org/CAS Testing

-----------------------------------------------------------------

"We must understand that technologies
like these are the way of the future."

-----------------------------------------------------------------

.

Relevant Pages

  • Re: An exact 1-D integration challenge - 53 - Proud Earthling, go and defeat all the dol
    ... fold integration over real line into integration over positives ... Then, also verify its validity: ... We thus has a half-baked proof that the integral equals zero. ...
    (sci.math.symbolic)
  • Proof of Integral Formula
    ... I wanted to verify the formula. ... this result by actually being able to do the integration. ... actually evaluated (I assume it's a legitimate way, although granted, ... you have to see the trick as to what Imust be), ...
    (sci.math)
  • Re: How Chapman-Kolmogorov implies Markov ??
    ... then dividing by p_1and using the conditional probability ... and we have an integration ... integral equals zero implies integrand equals zero. ... then follows the Chapman-Kolmogorov equation. ...
    (sci.physics)